build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'jacoco'
    id 'maven-publish'
    id 'signing'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'checkstyle'
}

group 'com.telesign'
version '4.0.0'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenCentral()
}

checkstyle {
    toolVersion = '10.12.5'
    configFile = file("${rootDir}/config/checkstyle/checkstyle.xml")
    ignoreFailures = true
}

// Test configuration
test {
    useJUnit()
    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat "full"
        showStandardStreams = false
    }
}

// Task for linting
tasks.register('lint') {
    group = 'verification'
    description = 'Runs checkstyle linter'
    dependsOn 'checkstyleMain', 'checkstyleTest'
}

// Task for CI pipeline
tasks.register('ciTest') {
    group = 'verification'
    description = 'Runs tests and linter for CI/CD pipeline'
    dependsOn 'clean', 'test', 'lint'
}

// Task for release validation
tasks.register('validateRelease') {
    group = 'release'
    description = 'Validates code is ready for release'
    dependsOn 'ciTest', 'javadoc', 'sourcesJar', 'javadocJar'
    doLast {
        println "✓ Release validation completed successfully"
    }
}

jar {
    manifest {
        attributes 'Implementation-Version': project.version
    }
}

dependencies {
    implementation 'com.squareup.okhttp3:okhttp:[4.7.0,)'
    implementation 'com.google.code.gson:gson:[2.7,3.0)'

    testImplementation group: 'junit', name: 'junit', version: '[4.1,)'
    testImplementation group: 'com.squareup.okhttp3', name: 'mockwebserver', version: '[4.7.0,)'
}

jacocoTestReport {
    reports {
        csv.required = false
        html.required = true
        xml.required = true
        xml.destination = file("${buildDir}/reports/jacoco/report.xml")
    }
}

if (System.getenv('TRAVIS') == null) {

    tasks.register('javadocJar', Jar) {
        from tasks.javadoc
        archiveClassifier.set('javadoc')
    }

    tasks.register('sourcesJar', Jar) {
        from sourceSets.main.allSource
        archiveClassifier.set('sources')
    }

    tasks.register("fatJar", Jar) {
        archiveClassifier.set("all")
        from sourceSets.main.output

        dependsOn configurations.runtimeClasspath
        from {
            configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
            configurations.runtimeClasspath.files.collect {
                it.isDirectory() ? it : zipTree(it)
            }
        }
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }

    tasks.register('clearOldJar', Delete) {
        delete fileTree(dir: "build/libs", includes: [".bin"])
    }


    tasks.register('copyJar', Delete) {
        dependsOn("clearOldJar")
        from('fatJar')
        into('bin')
    }

    artifacts {
        archives jar
        archives javadocJar
        archives sourcesJar
    }

    signing {
        sign(publishing.publications)
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java
                artifact javadocJar
                artifact sourcesJar
                artifact fatJar

                groupId = 'com.telesign'
                artifactId = 'telesign'
                version = '4.0.0'

                pom {
                    name = 'Telesign SDK'
                    description = 'The Telesign Java SDK is a Java library that provides an interface to Telesign Web ' +
                            'Services. Telesign Web Services conform to the REST Web Service Design Model. Services are ' +
                            'exposed as URI-addressable resources through the set of RESTful procedures in our Telesign ' +
                            'REST API.'
                    url = 'https://github.com/TeleSign/java_telesign'

                    scm {
                        connection = 'scm:git:https://github.com/TeleSign/java_telesign.git'
                        developerConnection = 'scm:git:git@github.com:TeleSign/java_telesign.git'
                        url = 'https://github.com/TeleSign/java_telesign'
                    }

                    licenses {
                        license {
                            name = 'MIT License'
                            url = 'http://www.opensource.org/licenses/mit-license.php'
                        }
                        license {
                            name = 'Apache Software License (ASL) version 2.0'
                            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }

                    developers {
                        developer {
                            name = 'Telesign Corp.'
                            organizationUrl = 'https://www.telesign.com'
                        }
                    }
                }
            }
        }

    }
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}